VBscript help

Cheekz185 · 05-16-2008, 08:29 PM

Ok so the company I work for has 6000+ PC's. I came across a VB script where you enter a username and it returns the computer name that person is on. Here is the code: (from http://windowsitpro.com/windowsscrip...ged-on-to.html)

Code:

Option Explicit

Dim objShell, objExec, strUserName, strOutput, intLine
Dim intPosition, strIP, arrEntrySplit, strComputerName, intRemote

Set objShell = CreateObject("WScript.Shell")
strUserName = InputBox("Please enter a user name:" & vbCRLF & vbCRLF & _
   "(Press [ENTER] or click [CANCEL] to exit...)", _
   "User Computer Name Locator", "")

Do While strUserName <> ""
   Set objExec = objShell.Exec("NETSH WINS SERVER \\WinsServerName SHOW NAME " _
      & strUserName & " 03")
   For intLine = 1 To 4
      objExec.StdOut.ReadLine
   Next
   If objExec.StdOut.ReadLine <> "The name does not exist in the WINS database." Then
      For intLine = 1 To 5
         objExec.StdOut.ReadLine
      Next
      strOutput = objExec.StdOut.ReadLine
      If Left(strOutput,10) <> "IP Address" Then
         strOutput = objExec.StdOut.ReadLine
      End If
      intPosition = InStr(strOutput, ":")
      strIP = Right(strOutput, (Len(strOutput) - intPosition) - 0)
      Set objExec = objShell.Exec("NBTSTAT -A " & strIP)
      Do While Not objExec.StdOut.AtEndOfStream
         strOutput = objExec.StdOut.ReadLine
         If InStr(strOutput,"<03>") <> 0 Then
            arrEntrySplit = Split(strOutput)
            If UCase(arrEntrySplit(4)) <> UCase(strUserName) And _
               UCase(arrEntrySplit(4)) <> UCase(strComputerName) And _
               UCase(arrEntrySplit(4)) <> strComputerName & "$" Then
               strComputerName = strComputerName & UCase(arrEntrySplit(4))
            End If
         End If
      Loop
      If strComputerName <> "" Then
         MsgBox "The requested user '" & strUserName & _
            "' is logged on to: " & strComputerName,,"User Computer Name Locator"
      Else
         MsgBox "The requested user '" & strUserName & _
            "' doesn't appear to logged on to the network. "
      End If
   Else
      MsgBox "The user was not found in the WINS database. ",, _
         "User Computer Name Locator"
   End If
   strComputerName = ""
   strUserName = InputBox("Please enter a user name:" & vbCRLF & vbCRLF & _
      "(Press [ENTER] or click [CANCEL] to exit...)", _
      "User Computer Name Locator", "")
Loop

Here is the thing, the script works really well but unfortunately, it only works with Windows 2000 based PC's. It does not work for Windows XP based PC's. Could somebody help me fix it up where it would work on both 2000 and XP systems?

Enforcer · 05-17-2008, 07:21 AM

I think that's because NBTSTAT -A's output on XP machines is different to 2000 machines.

The significant difference I can see is that is does not provide the username.

One way would be to set up a logon script that updates a database as user logs in as to which PC they are on. And another to run when they logout that removes them fro that PC. (one issue with this would be if they PC crashes they wouldn't be updated)

Or have a program that runs in the background that updates that info periodically.

However isn't there some kind of server tool that allows this info to be found.

Cheekz185 · 05-17-2008, 11:14 AM

What I don't understand is if works for win2000 y not xp? Their has got to be a way where the script will work. I was reading something about the objWMIService.

The company I work for probably won't let us install ne software for this. So the script is the best and easiest way

Enforcer · 05-17-2008, 11:31 AM

Like I said, NBTSTAT does NOT appear to give the username in XP but it does for Win2K.

almera · 05-17-2008, 12:41 PM

http://www.pcreview.co.uk/forums/thread-634456.php